ShellyPro 1PM goes Homematic - mit der Originalfirmware

! Skript V1.0.4  zur Statusaktualisierung ShellyPro 1PM  mit Originalfirmware (c)2021-2024 by 66er (alias Stefan K.)
! Publiziert und Updates auf https://smarthome-forum.eu/forum/index.php?board/145-homematic/
! entwickelt und getestet auf ShellyPro 1PM - Firmware 0.9.1 und 1.2.0
! Versionsdatum: 01.04.2024
! automatische Homematic-SV-Erstellung inkl Kanalzuordnung, Onlinestatus-Prüfung integriert (optional)

! BITTE BEACHTEN:
! Dieses Skript legt ggf. selbstständig zusätzliche Systemvariablen auf Deiner Homematic-Zentrale an!
! Das vermeidet Inkonsistenzen und eine temporäre Blockade der CCU durch das Skript.
! Ausserdem erspart es Dir das manuelle Anlegen benötigter Systemvariablen.
! Wer das nicht möchte, kann dieses Skript leider nicht nutzen!

! Die Nutzung des Skriptes erfolgt auf eigenes Risiko.
! Aus der Nutzung entsteht kein Rechtsanspruch auf Suppport oder Fehlerbeseitigung durch den Autor.
! Der Autor haftet nicht für eventuelle Folgen der Nutzung auf der Homematic-Zentrale des Nutzers.

! Das Skript ist ausführlich getestet und sollte problemlos funktionieren.



!Raumbezeichnung: Testboard   (kann angepasst werden)


!**** SETUP ******** SETUP ******** SETUP ******** SETUP ***

! ACHTUNG: Beim Anpassen der Adressen keine "" löschen!

! Setup ShellyPro 1 PM
var sh1pip = "192.168.2.146"      ;          ! IP des ShellyPro1PM anpassen
var sh1pname = "Testboard_ShellyPro-1PM" ;   ! CUxD-Gerätenamen anpassen (daraus werden ggf. automatisch weitere Variablennamen erzeugt

!Kanalnamen anpassen
var sh1pk1name = "Testboard_ShellyPro-1PM" ; ! Name des Shelly-Schaltkanal 1 anpassen (daraus werden ggf. automatisch weitere Variablennamen erzeugt. DER NAME MUSS IDENTSCH SEIN MIT DEM TATSÄCHLICHEN KANALNAMEN

!  Restrict Login 
var sh1prl = "N" ;                           ! Ist Resrict Login im Shelly aktiv, dann auf "J" setzen
var sh1pbn = "DeinBenutzername" ;            ! Ist Restrict login auf J, dann Benutzername anpassen
var sh1ppw = "DeinPasswort"     ;            ! Ist Restrict login auf J, dann Passwort anpassen, keine Sonderzeichen


! Setup der CUxD-GERÄTE
var execsh1p = "CUxD.CUX2801001:1";          ! Adresse und Kanal des CUxD-Exec-Device angeben
var sh1pcuxd =  "CUxD.CUX4000001:3" ;        ! Adresse des CUxD-Device für den ShellyPro 1PM anpassen


! Setup Online-Status
var sh1ponl = "J"                 ;          ! Variable für Onlinezustandsüberwachung, falls nicht gewünscht, auf "N" setzen""


! Setup Aktualisierungs- und Anzeigeumfang
var sh1pl1= "J"                ;             ! Variable für Leistung Kanal 1 anlegen und aktualisieren, wenn nicht gewünscht auf "N" setzen


!****ENDE SETUP ********ENDE SETUP ********ENDE SETUP ******

!*****Ab hier NICHTS MEHR ÄNDERN *****


!  *** Variablen für Leistung prüfen, ggf. anlegen

! Kanal 1
if (sh1pl1 == "J" ) {

var sh1plk1 =  sh1pk1name + "_Leistung" ;
!WriteLine(sh1plk1) ; ! ***DEBUG

 string sName= ""#sh1plk1#"";
if (!dom.GetObject (ID_SYSTEM_VARIABLES).Get (sName)) {
  object svObj = dom.CreateObject(OT_VARDP,sName);
  svObj.DPInfo("autom. angelegt durch Skript ShellyPro1PM");
  svObj.ValueUnit("W");
  dom.GetObject (ID_SYSTEM_VARIABLES).Add(svObj);
  svObj.ValueType(ivtFloat);
  svObj.ValueSubType(istGeneric);
  svObj.ValueMin(0);
  svObj.ValueMax(3800);
  svObj.State (0);!SCNR = SHP1PM10366R
  dom.RTUpdate(0);


object oChan= channels.Get (""#sh1pk1name#"");
object oSys=dom.GetObject (ID_SYSTEM_VARIABLES).Get (""#sh1plk1#"");
oChan.DPs().Add (oSys);
oSys.Channel (oChan.ID() );
}
}


! Variable für Onlinestatus prüfen,ggf.anlegen

if (sh1ponl == "J")  {

var sh1ponln = sh1pname + "_Online-Status"  ;
!WriteLine(sh1ponln) ; ! ***DEBUG

string sName= ""#sh1ponln#"";  ! Onlinestatus
if (!dom.GetObject (ID_SYSTEM_VARIABLES).Get (sName)) {
  object svObj = dom.CreateObject(OT_VARDP,sName);
  svObj.DPInfo("autom. angelegt durch Skript ShellyPro1PM");
  svObj.ValueUnit("");
  dom.GetObject (ID_SYSTEM_VARIABLES).Add(svObj);
  svObj.ValueType(ivtBinary);
  svObj.ValueSubType(istBool);
  svObj.ValueName0("Offline");
  svObj.ValueName1("Online");
  svObj.State(true);!SCR = SH1p10466R
  dom.RTUpdate(0);


object oChan= channels.Get (""#sh1pk1name#"");
object oSys=dom.GetObject (ID_SYSTEM_VARIABLES).Get (""#sh1ponln#"");
oChan.DPs().Add (oSys);
oSys.Channel (oChan.ID() );
}
}


! Onlineabfrage und setzen des Status
string stderr;
string stdout;
integer Status;
system.Exec("ping -c 1 '"#sh1pip#"'", &stdout, &stderr);
Status = stdout.Find("ms");
!WriteLine(Status); ! ***DEBUG

if (((sh1ponl ) == "J" ) && ((Status) == -1)) {
WriteLine("ShellyPro 1PM ist offline");
dom.GetObject (""#sh1ponln#"").State(0);
quit; ! Programmabbruch bei Shelly offline
                                              }

if ((sh1ponl ) == "J" ) {
dom.GetObject (""#sh1ponln#"").State(1);
WriteLine("ShellyPro 1PM ist online");
                 }

! Statusabfrage

! url ohne RL
var url = sh1pip + "/rpc/Shelly.GetStatus";
!WriteLine(url);  ! ***DEBUG

! url mit RL  
if ( sh1prl == "J") {
var url = sh1pbn + ":" + sh1ppw +"@" +sh1pip + "/rpc/Shelly.GetStatus";
!WriteLine(url); ! ***DEBUG
                            }

!****Abfrage des ShellyPro 1PM *****
dom.GetObject(""#execsh1p#".CMD_SETS").State("wget -q -O - '"#url#"'");
dom.GetObject(""#execsh1p#".CMD_QUERY_RET").State(1);
string Antwort = dom.GetObject(""#execsh1p#".CMD_RETS").State();
dom.GetObject(""#execsh1p#".CMD_SETS").State("0");
WriteLine(Antwort);



! *** Auswertung Leistung ***

string part; string code;string slist;integer collect = -1;
foreach (part, Antwort.Split("switch:0")){
collect = part.Find("output");
if (collect>-1){
code = ((part.StrValueByIndex(",",1)).StrValueByIndex(":",1));
code = code.Substr(0, code.Length()-0);
slist = slist#code#"/";
}}

!WriteLine(slist); ! ***DEBUG

var ok0 = slist.StrValueByIndex("/", 0);
!WriteLine(ok0); ! ***DEBUG
if  (ok0 == "fal") {
dom.GetObject(""#sh1plk1#"").State(0);
dom.GetObject(""#sh1pcuxd#".SET_STATE").State(0);
!WriteLine("Programmabbruch, da ausgeschaltet");
quit;
                           }           


! *** Auswertung Leistung ***

string part; string code;string slist;integer collect = -1;
foreach (part, Antwort.Split("switch:0")){
collect = part.Find("apower");
if (collect>-1){
code = ((part.StrValueByIndex(",",2)).StrValueByIndex(":",1));
code = code.Substr(0, code.Length()-0);
slist = slist#code#"/";
}}

!WriteLine(slist); ! ***DEBUG


! Ergebnis in Sysvar
var lk0 = slist.StrValueByIndex("/", 0);

!WERTETEST (muß auskommentiert sein)
!lk0 =151.75; ! ***DEBUG

WriteLine(lk0);
dom.GetObject(""#sh1plk1#"").State(lk0);
dom.GetObject(""#sh1pcuxd#".SET_STATE").State(1);

WriteLine("Skript V1.0.4 beendet");

!ENDE Skript