"Keep alive"- Überwachung für Zählerstandvariablen, z.B. des 3EM

! Skript V1.0.0 zur Überwachung einer Zählersystemvariablen (c)2022 by 66er (alias Stefan K.)
! Publiziert und Updates auf https://smarthome-forum.eu/forum/index.php?board/145-homematic/
! entwickelt und getestet auf Shelly3EM
! Versionsdatum: 27.03.2022

! BITTE BEACHTEN:
! Dieses Skript legt selbstständig zusätzliche Systemvariablen auf Deiner Homematic-Zentrale an!
! Das vermeidet Inkonsistenzen und eine temporäre Blockade der CCU durch das Skript.
! Ausserdem erspart es Dir das manuelle Anlegen benötigter Systemvariablen.
! Wer das nicht möchte, kann dieses Skript leider nicht nutzen!

! Die Nutzung des Skriptes erfolgt auf eigenes Risiko.
! Aus der Nutzung entsteht kein Rechtsanspruch auf Suppport oder Fehlerbeseitigung durch den Autor.
! Der Autor haftet nicht für eventuelle Folgen der Nutzung auf der Homematic-Zentrale des Nutzers.

! Das Skript ist ausführlich getestet und sollte problemlos funktionieren.


!**********             **********
!* SETUP !*             * SETUP !*
!**********             **********

! überwacht wird: 3EM Sauna   (kann angepasst werden)

! SETUP des zu überwachenden Gerätes und der zu überwachenden Variablen (1 pro Gerät reicht!)
!Achtung: Bei der Anpassung des Setup kein "" löschen!!!

var gip = "192.168.1.166" ;             ! IP des Gerätes zu der die zu überwachende Variable gehört anpassen
var gvar = "3EM_Sauna_TZ-Verbrauch" ; ! Name der Systemvariablen anpassen
var gcch = "CUX4000009:1" ;           ! Kanal des zu überwachenden Gerätes, dem die Variable zugeordnet werden soll
var gname = "Shelly 3EM Sauna";       ! Name des Shelly-Kanals mit der zu überwachenden Variable angeben, NAME MUSS IDENTISCH SEIN MIT DEM TATSÄCHLICHEN KANALNAMEN
var ggen = "1";                       ! Shelly-Generation anpassen: 1 = Shelly Gen.1 und 2 = Shelly Gen.2


!SETUP Funktionsumfang

var grb = "J" ;                       ! Im Fehlerfall wird ein Reboot-Befehl an den Shelly ausgelöst, wenn nicht gewünscht auf "N" setzen

!SETUP CUxD-Ecec
var gexec = "CUxD.CUX2801001:12"    ;       ! Kanal des CUxD-Exec-Kanal anpassen, der zur Kommunikation verwendet werden soll



! ***** ENDE SETUP ***
!Ab hier NICHTS MEHR ÄNDERN !


! Backupvariable für die zu überwachende Variable anlegen

string sName= gvar + "_backup";
var sbname = sName;
!WriteLine(sName);

if (!dom.GetObject (ID_SYSTEM_VARIABLES).Get (sName)) {
  object svObj = dom.CreateObject(OT_VARDP,sName);
  svObj.DPInfo("autom. angelegt durch Skript Werteüberwachung");
  svObj.ValueUnit("");! SVU10066er
  dom.GetObject (ID_SYSTEM_VARIABLES).Add(svObj);
  svObj.ValueType(ivtFloat);
  svObj.ValueSubType(istGeneric);
  svObj.ValueMin(0);
  svObj.ValueMax(65000);
  svObj.State (0);
  dom.RTUpdate(0);
}


! Egebnisvariable anlegen und zuordnen

var varname =  gvar + "_letzte-Wertabfrage";

string sName=  varname;
if (!dom.GetObject (ID_SYSTEM_VARIABLES).Get (sName)) {
  object svObj = dom.CreateObject(OT_VARDP,sName);
  svObj.DPInfo("autom. angelegt durch Skript Werteüberwachung");
  svObj.ValueUnit(""); !SVU10066er
  dom.GetObject (ID_SYSTEM_VARIABLES).Add(svObj);
  svObj.ValueType(ivtInteger);
  svObj.ValueSubType(istEnum);
  svObj.ValueList("erfolgreich;Wert unverändert;Reboot ausgelöst;Reboot erfolglos;unplausibel, bitte prüfen!");
  svObj.State (0);
  dom.RTUpdate(0);
}


object oChan= channels.Get (""#gname#"");
object oSys=dom.GetObject (ID_SYSTEM_VARIABLES).Get(""#varname#"");
oChan.DPs().Add (oSys);
oSys.Channel (oChan.ID() );


! Reboot Url

if (ggen == "1"){
string url;
url = gip + "/reboot";
WriteLine(url);
}


if (ggen == "2"){
string url;
url = gip + "/rpc/Shelly.Reboot";
WriteLine(url);
}


! Werte auslesen

var wertak = dom.GetObject(""#gvar#"").Value();
WriteLine(wertak);     ! DEBUG

var wertbu = dom.GetObject(""#sbname#"").Value();
WriteLine(wertbu);     ! DEBUG

var svstat = dom.GetObject(""#varname#"").State();
WriteLine(svstat);     ! DEBUG

! Vergleich und Verarbeitung

!Testwert (Folgezeile muss auskommentiert sein wenn Wert eingetragen)
!wertak = 1.1 ;

if (wertak > wertbu)  {
WriteLine("neuer Wert i.O."); !DEBUG
dom.GetObject(""#sbname#"").State(wertak);
dom.GetObject(""#varname#"").State(0); 
WriteLine("Programm beendet, da Abfrage plausibel.");!DEBUG
quit;
}

if ((wertak == wertbu) && (svstat == "0")) {
!dom.GetObject(""#sbname#"").State(wertak); !kein Schreiben da unverändert
dom.GetObject(""#varname#"").State(1);! keine Veränderung
}

elseif ((wertak == wertbu) && (svstat == "1")) {


!Erreichbarkeitsprüfung und ggf. reboot-Befehl

! Onlineabfrage
string stderr;
string stdout;
integer Status;
system.Exec("ping -c 1 '"#gip#"'", &stdout, &stderr);
Status = stdout.Find("ms");
WriteLine("Ergebnis ping = " + Status);

! Auswertung Onlineabfrage

if (Status <> "-1") {
!WriteLine("erreichbar");
    dom.GetObject(""#gexec#".CMD_EXEC").State("wget -q -O /dev/null " # url);
    WriteLine(url + "   gesendet");
    dom.GetObject(""#varname#"").State(2);
    WriteLine("Reboot ausgelöst mit:" + url ); !DEBUG
}

if (Status == "-1") {
 WriteLine("Zielgerät offline");               !DEBUG
 dom.GetObject(""#varname#"").State(3);
 quit;

}

}

elseif ((wertak == wertbu) && (svstat >= "2")) {

dom.GetObject(""#varname#"").State(3)}


elseif (wertak < wertbu) {
!Aktuell < Backup
dom.GetObject(""#varname#"").State(4)}



WriteLine("Skript SV-Überwachung V1.0.0 beendet");"

! ENDE SKRIPT