Shelly Plus Plug S Homematic

! Skript V1.0.1 zur Statusaktualisierung ShellyPlusPlugS mit Originalfirmware (c)2023-2024 by 66er (alias Stefan K.)
! Publiziert und Updates auf https://smarthome-forum.eu/forum/index.php?board/145-homematic/
! entwickelt und getestet auf ShellyPlusPlugS-Firmware  0.14.1
! Versionsdatum:01.04.2024  : 
! automatische Homematic-SV-Erstellung inkl Kanalzuordnung, Onlinestatus-Prüfung integriert (optional)


! BITTE BEACHTEN:
! Dieses Skript legt ggf. selbstständig zusätzliche Systemvariablen auf Deiner Homematic-Zentrale an!
! Das vermeidet Inkonsistenzen und eine temporäre Blockade der CCU durch das Skript.
! Ausserdem erspart es Dir das manuelle Anlegen benötigter Systemvariablen.
! Wer das nicht möchte, kann dieses Skript leider nicht nutzen!

! Die Nutzung des Skriptes erfolgt auf eigenes Risiko.
! Aus der Nutzung entsteht kein Rechtsanspruch auf Suppport oder Fehlerbeseitigung durch den Autor.
! Der Autor haftet nicht für eventuelle Folgen der Nutzung auf der Homematic-Zentrale des Nutzers.

! Das Skript ist ausführlich getestet und sollte problemlos funktionieren.



!Raumbezeichnung: Test-BT  (kann angepasst werden)


!**** SETUP ******** SETUP ******** SETUP ******** SETUP ***

! ACHTUNG: Beim Anpassen der Adressen keine "" löschen!

! Setup ShellyPlus PlugS
var shp1ip = "192.168.178.94"      ;           ! IP des ShellyPlus1PM anpassen
var shp1name = "ShellySteckdose" ;         ! CUxD-Gerätenamen anpassen (daraus werden ggf. automatisch weitere Variablennamen erzeugt

! Setup der CUxD-GERÄTE
var execshp1 = "CUxD.CUX2801001:1";          ! Adresse und Kanal des CUxD-Exec-Device angeben
var shp1cuxd =  "CUxD.CUX4000004:1" ;        ! Adresse des CUxD-Device für den ShellyPlusPlugS anpassen


! Setup Online-Status
var shp1onl = "J"                 ;           ! Variable für Onlinezustandsüberwachung, falls nicht gewünscht, auf "N" setzen""


! Setup Aktualisierungs- und Anzeigeumfang
var shp1a = "J"                ;              ! Schaltstatus aktualisieren, wenn nicht gewünscht auf "N" setzen
var shpl1p = "J"               ;              ! Verbrauch aktualisieren, wenn nicht gewünscht auf "N" setzen

!****ENDE SETUP ********ENDE SETUP ********ENDE SETUP ******

!*****Ab hier NICHTS MEHR ÄNDERN *****



!  *** Variable für Leistung prüfen, ggf. anlegen

if (shpl1p == "J" ) {

var shpl1pk1 =  shp1name + "_Leistung" ;
!WriteLine(shpl1pk1) ;

 string sName= ""#shpl1pk1#"";
if (!dom.GetObject (ID_SYSTEM_VARIABLES).Get (sName)) {
  object svObj = dom.CreateObject(OT_VARDP,sName);
  svObj.DPInfo("autom. angelegt durch Skript ShellyPlus1PM");
  svObj.ValueUnit("W");
  dom.GetObject (ID_SYSTEM_VARIABLES).Add(svObj);
  svObj.ValueType(ivtFloat);
  svObj.ValueSubType(istGeneric);
  svObj.ValueMin(0);
  svObj.ValueMax(3800);
  svObj.State (0);!SCNR = SHPPS10066R
  dom.RTUpdate(0);


object oChan= channels.Get (""#shp1name#"");
object oSys=dom.GetObject (ID_SYSTEM_VARIABLES).Get (""#shpl1pk1#"");
oChan.DPs().Add (oSys);
oSys.Channel (oChan.ID() );
}
}


! Variable für Onlinestatus prüfen,ggf.anlegen

if (shp1onl == "J")  {

var shp1onln = shp1name + "_Online-Status" ;
!WriteLine(shp1onln) ;

string sName= ""#shp1onln#"";  ! Onlinestatus
if (!dom.GetObject (ID_SYSTEM_VARIABLES).Get (sName)) {
  object svObj = dom.CreateObject(OT_VARDP,sName);
  svObj.DPInfo("autom. angelegt durch Skript ShellyPlus1PM");
  svObj.ValueUnit("");
  dom.GetObject (ID_SYSTEM_VARIABLES).Add(svObj);
  svObj.ValueType(ivtBinary);
  svObj.ValueSubType(istBool);
  svObj.ValueName0("Offline");
  svObj.ValueName1("Online");
  svObj.State(true);!SCR = SHPPS10166R
  dom.RTUpdate(0);


object oChan= channels.Get (""#shp1name#"");
object oSys=dom.GetObject (ID_SYSTEM_VARIABLES).Get (""#shp1onln#"");
oChan.DPs().Add (oSys);
oSys.Channel (oChan.ID() );
}
}


! Onlineabfrage und setzen des Status
string stderr;
string stdout;
integer Status;
system.Exec("ping -c 1 '"#shp1ip#"'", &stdout, &stderr);
Status = stdout.Find("ms");
WriteLine(Status);


if (((shp1onl ) == "J" ) && ((Status) == -1)) {
WriteLine("ShellyPlus1PM ist offline");
dom.GetObject (""#shp1onln#"").State(0);
quit; ! Programmabbruch bei Shelly offline
                                              }

if ((shp1onl ) == "J" ) {
dom.GetObject (""#shp1onln#"").State(1);
WriteLine("ShellyPlus1PM ist online"); 
                 }


! Statusabfrage

var url = shp1ip + "/rpc/switch.GetStatus?id=0";
WriteLine(url);

                          

!****Abfrage des ShellyPlusPlugS *****
WriteLine("Abfrage startet");
dom.GetObject(""#execshp1#".CMD_SETS").State("wget -q -O - '"#url#"'");
dom.GetObject(""#execshp1#".CMD_QUERY_RET").State(1);
string Antwort = dom.GetObject(""#execshp1#".CMD_RETS").State();
dom.GetObject(""#execshp1 #".CMD_SETS").State("0");
WriteLine(Antwort);

string output = Antwort;

string part; string code;string slist;integer collect = -1;
foreach (part,output.Split("switch:0")){
collect = part.Find("output");
if (collect>-1){
code = ((part.StrValueByIndex(",",1)).StrValueByIndex(":",1));
code = code.Substr(0, code.Length()-0);
slist = slist#code#"/";
}}

!WriteLine(slist);

var out = slist.StrValueByIndex("/", 0);
!WriteLine(out);

if (out == "true") {
dom.GetObject(""#shp1cuxd#".SET_STATE").State(1);
WriteLine("Zustand EIN festgestellt");
                            }

if (out != "true") {
WriteLine("Zustand AUS festgestellt");
dom.GetObject(""#shp1cuxd#".SET_STATE").State(0);
dom.GetObject(""#shpl1pk1#"").State(0);
WriteLine("Programm beendet, Shelly ist ausgeschaltet!");
quit;
        }


! ***Auswertung Leistung
string output = Antwort;


!Testantwort ! FOLGEZEILE MUSS auskommentiert sein, wenn String vorhanden


string part; string code;string slist;integer collect = -1;
foreach (part, output.Split("switch0")){
collect = part.Find("apower");
if (collect>-1){
code = ((part.StrValueByIndex(",",2)).StrValueByIndex(":",1));
code = code.Substr(0, code.Length()-0);
slist = slist#code#"/";
}}

WriteLine(slist);

var lpk1 = slist.StrValueByIndex("/", 0);

if (shpl1p == "J")  {
dom.GetObject(""#shpl1pk1#"").State(lpk1);
}

WriteLine("Skript ShellyPlusPlugS V1.0.0 beendet");

!ENDE SKRIPT