3EM + CCU = ein smarter Stromzähler

! Skript V2.0.4 für den "smarten Stromzähler" mit Shelly 3EM mit Originalfirmware (c)2020 by 66er (alias Stefan K.) - Alle Rechte vorbehalten
! 3EM als Verbrauchszähler, Anzeige der aktuellen Last je Phase und einem Tageszähler inkl. Kostenanzeige
! Publiziert und Updates auf https://smarthome-forum.eu/forum/index.php?board/145-homematic/
! Danke an Maik (neo-V) für die Idee und Zusammenarbeit bei der Online-Erkennung



!Sauna        (nur zur Orientierung, ggf anpassen)


! ACHTUNG:
! Im Setup KEINE " " LÖSCHEN!

! ****** SETUP         SETUP      SETUP    SETUP *****

! Setup des Shelly 3EM *******************************
var url = "http://192.168.1.166/status"; ! IP-Adresse des Shelly  anpassen

! Setup der CUxD-GERÄTE ******************************
var exec3em = "CUxD.CUX2801001:6"; ! Adresse und Kanal des CUxD-Exec-Device anpassen

!Setup der SYSTEMVARIABLEN ***************************

! Setup Anzeige der 3Phasen
var svLv = "J";! Ohne Variablen für die aktuelle Leistung auf "N" setzen

var svL1 = "3EM-Sauna_aktuell-L1"; !Name der SV für den aktuellen Verbrauch L1 anpassen
var svL2 = "3EM-Sauna_aktuell-L2"; !Name der SV für den aktuellen Verbrauch L2 anpassen
var svL3 = "3EM-Sauna_aktuell-L3"; !Name der SV für den aktuellen Verbrauch L3 anpassen

! Setup der Verbrauchsanzeige ************************
var svVges = "3EM-Sauna_Verbrauch-gesamt_2020";   ! Name der SV für den Gesamtverbrauch anpassen
var svVbu = "3EM-Sauna_Gesamtverbrauch-Backup";   ! Name der SV für den Backupwert eintragen
var svVbu2 = "3EM-Sauna_Gesamtverbrauch-Backup2"; ! Name der SV für den Backupwert2 eintragen

! Setup der Kostenanzeige ****************************
var sykov = "J"; ! Kostenvariable vorhanden J oder N setzen
real pkwh = "0.2863"; ! Preis je kWh angeben
var syko = "3EM-Sauna_Kosten"; ! Name der SV für die Verbrauchskosten

! Setup Tageszähler **********************************
var emtzv = "J"; !Tageszähler vorhanden J oder N setzen
var emtz = "3EM_Sauna_TZ-Verbrauch"; ! Name der SV für den Backupwert eintragen
var emtzk = "3EM_Sauna_TZ-Kosten"; ! Name der SV für die Tageskostenwert eintragen
var emtzs = "3EM_Sauna_TZ-Startwert"; ! Name der SV für den Startwert des Tageszählers eintragen

! Setup Prüfung und Anzeige Onlinestatus *************
var emp = "1";  ! Ohne Onlienstatusprüfung auf 0 setzen
var padr = "192.168.1.166"; ! IP des Shelly 3EM eintragen
var svonl = "Onlinestatus_3EM-Sauna" ; ! Name der SV für den Onlinestatus angeben

!****ENDE SETUP ********ENDE SETUP ********ENDE SETUP ******


! AB HIER NICHTS MEHR ÄNDERN

! Onlineabfrage und setzen des Status
string stderr;
string stdout;
integer Status;
system.Exec("ping -c 1 '"#padr#"'", &stdout, &stderr);
Status = stdout.Find("ms");

if (((emp) == 1 ) && ((Status) == -1)) {
dom.GetObject (""#svonl#"").State(0);
quit; ! Programmabbruch bei Shelly offline
                                       }

if ((emp) == 1 ) {
dom.GetObject (""#svonl#"").State(1);
                 }

!****Abfrage des Shelly 3EM *****
dom.GetObject(""#exec3em#".CMD_SETS").State("wget -q -O - '"#url#"'");
dom.GetObject(""#exec3em#".CMD_QUERY_RET").State(1);
string Antwort = dom.GetObject(""#exec3em#".CMD_RETS").State();
string t = dom.GetObject(""#exec3em#".CMD_RETS").State();
dom.GetObject(""#exec3em#".CMD_SETS").State("0");
!WriteLine(Antwort);


!**** Auswertung der Total-Werte je Phase ****
string output = Antwort;

string part; string code;string slist;integer collect = -1;
foreach (part, output.Split("emeters")){
collect = part.Find("total");
if (collect>-1){
code = ((part.StrValueByIndex(",",1)).StrValueByIndex(":",1));
code = code.Substr(0, code.Length()-1);
slist = slist#code#"/";
}}


! Ergebnis in Einzelwerte auflösen
var pl1 = slist.StrValueByIndex("/", 0);
var pl2 = slist.StrValueByIndex("/", 1);
var pl3 = slist.StrValueByIndex("/", 2);


! Berechnung Gesamtverbrauch in Watt
var pg = pl1.ToFloat() + pl2.ToFloat() + pl3.ToFloat();
!WriteLine("Berechnung Gesamtverbrauch abgeschlossen");


! Berechnung und Setzen der Variablen (Gesamtverbrauch)
var pjg = dom.GetObject(""#svVges#"").State();
var pbu = dom.GetObject(""#svVbu#"").State();
var pbu2 = dom.GetObject(""#svVbu2#"").State();
integer pz;

!Normalbetrieb
if (pg >= (pbu*1000))

    {
dom.GetObject(""#svVges#"").State(pg/1000);
dom.GetObject(""#svVbu#"").State(pg/1000);
dom.GetObject(""#svVbu2#"").State(pg/1000);
    }

elseif ((pg < (pbu*1000)) && (pg < (pbu2*1000)))
    {
!nach Wertereset im Shelly
pz = pjg + (pg/1000) ;
dom.GetObject(""#svVges#"").State(pz);
dom.GetObject(""#svVbu#"").State(pz);                             
dom.GetObject(""#svVbu2#"").State(pg/1000);
    }

elseif ((pg < (pbu*1000)) && (pg > (pbu2*1000)))
    {
pz = pjg + ((pg/1000) - pbu2) ;
dom.GetObject(""#svVges#"").State(pz);
dom.GetObject(""#svVbu#"").State(pz);
dom.GetObject(""#svVbu2#"").State(pg/1000);
    }
!WriteLine("Verbrauchsberechnung insgesamt abgeschlossen");


!Betrag berechnen
var vbw = dom.GetObject(""#svVges#"").State();
var sykoberg = vbw * pkwh.ToFloat();
if (sykov == "J") {dom.GetObject(""#syko#"").State(sykoberg);} ;
!WriteLine("Kostenberechnung gesamt abgeschlossen");! SH3EM20266R


! aktuelle Last
string output = Antwort;

string part; string code;string slist;integer collect = -1;
foreach (part, output.Split("{")){
collect = part.Find("power");

if (collect>-1){
code = ((part.StrValueByIndex(":",1)).StrValueByIndex(",",0));
code = code.Substr(0, code.Length()-1);
slist = slist#code#"/"; !SCN3EM20466R

}}
!WriteLine(slist);! SH3EM20266R

var l1 = slist.StrValueByIndex("/", 1);
var l2 = slist.StrValueByIndex("/", 2);
var l3 = slist.StrValueByIndex("/", 3);


!Werte in Systemvariablen schreiben
if ((svLv) == "J") {dom.GetObject(""#svL1#"").State(l1.ToFloat()); };
if ((svLv) == "J") {dom.GetObject(""#svL2#"").State(l2.ToFloat()); };
if ((svLv) == "J") {dom.GetObject(""#svL3#"").State(l3.ToFloat()); };
!WriteLine("Berechnung aktuelle Last der 3 Phasen abgeschlossen");


! Tageszähler
if (emtzv == "N") {quit ; };

string sw = dom.GetObject(""#emtzs#"").State();
string pg = dom.GetObject(""#svVges#"").State();
var tz = pg - sw;
!WriteLine(tz + "TZ");

dom.GetObject(""#emtz#"").State(tz);
var tzk = tz * pkwh.ToFloat();
dom.GetObject(""#emtzk#"").State(tzk);

!WriteLine("Skript beendet!");

!Ende Skript